您现在的位置是:首页 > 数字电源 > 技术解析

单片机键盘处理程序设计举例

时间:2017-10-11 来源:

1、键盘与的连接

 

 

<键盘连接>

图3

 

 

<单片机与键盘接口图>

图4

2、通过1/0口连接。将每个按钮的一端接到单片机的I/O口,另一端接地,这是最简单的办法,如图3所示是实验板上按钮的接法,四个按钮分别接到P3.2 、P3.3、P3.4和P3.5。对于这种键各程序能采用持续查询的办法,功能就是:检测是否有键闭合,如有键闭合,则去除键抖动,判断键号并转入对应的键处理。下面给出一个例程。其功能很简单,四个键定义如下:

P3.2:开始,按此键则灯开始流动(由上而下)

P3.3:停止,按此键则停止流动,所有灯为暗

P3.4:上,按此键则灯由上向下流动

P3.5:下,按此键则灯由下向上流动

UpDown EQU 00H ;上下行标志

StartEnd EQU 01H ;起动及停止标志

LAMPCODE EQU 21H ;存放流动的数据代码

以下程序功能很简单,但它演示了一个单片机程序的基本思路,程序本身很简单,也不很实用,实际工作中还会有好多要考虑的因素,比如主循环每次都调用灯的循环程序,会造成按钮反应“迟钝”,而如果一直按着键不放,则灯不会再流动,一直要到松开手为止,等等,大家能仔细考虑一下这些问题,再想想有什么好的解决办法。

ORG 0000H

AJMP MAIN

ORG 30H

MAIN:

MOV SP,#5FH

MOV P1,#0FFH

CLR UpDown ;启动时处于向上的状态

CLR StartEnd ;启动时处于停止状态

MOV LAMPCODE,#0FEH ;单灯流动的代码

LOOP:

ACALL KEY ;调用键盘程序

JNB F0,LNEXT ;如果无键按下,则继续

ACALL KEYPROC ;不然调用键盘处理程序

LNEXT:

ACALL LAMP ;调用灯显示程序

AJMP LOOP ;反复循环,主程序到此结束

DELAY:

MOV R7,#100

D1: MOV R6,#100

DJNZ R6,$

DJNZ R7,D1

RET

;----------------------------------------延时程序,键盘处理中调用

KEYPROC:

MOV A,B ;从B寄存器中获取键值

JB ACC.2,KeyStart ;分析键的代码,某位被按下,则该位为1(因为在键盘程序中已取反)

JB ACC.3,KeyOver

JB ACC.4,KeyUp

JB ACC.5,KeyDown

AJMP KEY_RET

KeyStart:

SETB StartEnd ;第一个键按下后的处理

AJMP KEY_RET

KeyOver:

CLR StartEnd ;第二个键按下后的处理

AJMP KEY_RET

KeyUp: SETB UpDown ;第三个键按下后的处理

AJMP KEY_RET

KeyDown:

CLR UpDown ;第四个键按下后的处理

KEY_RET:RET

KEY:

CLR F0 ;清F0,表示无键按下。

ORL P3,#00111100B ;将P3口的接有键的四位置1

MOV A,P3 ;取P3的值

ORL A,#11000011B ;将其余4位置1

CPL A ;取反

JZ K_RET ;如果为0则一定无键按下

ACALL DELAY ;不然延时去键抖

ORL P3,#00111100B

MOV A,P3

ORL A,#11000011B

CPL A

JZ K_RET

MOV B,A ;确实有键按下,将键值存入B中

SETB F0 ;设置有键按下的标志

K_RET:

ORL P3,#00111100B ;此处循环等待键的释放

MOV A,P3

ORL A,#11000011B

CPL A

JZ K_RET1 ;直到读取的数据取反后为0说明键释放了,才从键盘处理程序中返回

AJMP K_RET

K_RET1:

RET

D500MS: ;流水灯的延迟时间

PUSH PSW

SETB RS0

MOV R7,#200

D51: MOV R6,#250

D52: NOP

NOP

NOP

NOP

DJNZ R6,D52

DJNZ R7,D51

POP PSW

RET

LAMP:

JB StartEnd,LampStart ;如果StartEnd=1,则启动

MOV P1,#0FFH

AJMP LAMPRET ;不然关闭所有显示,返回

LampStart:

JB UpDown,LAMPUP ;如果UpDown=1,则向上流动

MOV A,LAMPCODE

RL A ;实际就是左移位而已

MOV LAMPCODE,A

MOV P1,A

LCALL D500MS

AJMP LAMPRET

LAMPUP:

MOV A,LAMPCODE

RR A ;向下流动实际就是右移

MOV LAMPCODE,A

MOV P1,A

LCALL D500MS

LAMPRET:

RET

END

以上程序功能很简单,但它演示了一个单片机键盘处理程序的基本思路,程序本身很简单,也不很实用,实际工作中还会有好多要考虑的因素,比如主循环每次都调用灯的循环程序,会造成按钮反应“迟钝”,而如果一直按着键不放,则灯不会再流动,一直要到松开手为止,等等,大家能仔细考虑一下这些问题,再想想有什么好的解决办法。

换一批

延伸阅读

[疯狂史] 英特尔第一款完整的商业处理器已经44岁了

英特尔第一款完整的商业处理器已经44岁了

英特尔于1971年11月15日宣布了4004处理器及其芯片集,它是芯片巨人第一个完整的单片机和第一个商业微处理器。4004处理器有2300个晶体管,手指甲大小,计算性能与第一代电子计算机相当,但第一代计算机需要占据整间房......

关键字:英特尔 处理器 单片机

[真心话] 漫漫电子工程路:尝百鲜之后,我还是如此钟情于单片机

漫漫电子工程路:尝百鲜之后,我还是如此钟情于单片机

现在想起来,当时的情形还历历在目。当时工作非常艰辛,累得我是满地找牙。记得进厂的第一天,就加班通霄,以后天天晚上加班至12点,早上7点起床。......

关键字:电子工程师 单片机

[真心话] 一个实例简单明了告诉你为什么要用RTOS

一个实例简单明了告诉你为什么要用RTOS

对于搞单片机的特别用8051系列工程师来说,谈到单片机的RTOS,很多时候会问一句:“为什么要用RTOS?单片机就这一点资源,使用RTOS能保证效率吗?”......

关键字:单片机 RTOS

[真心话] 单片机大师郭天祥的大学六年,看看与你的有何不同?

单片机大师郭天祥的大学六年,看看与你的有何不同?

在哈尔滨工程大学五年,我在学校电子创新实验室呆了四年,这四年里创新实验室给我提供了良好的学习环境和完善的实验设备;在这里与众多电子爱好者的交流中,使我学到了更多的专业知识;在学校老师们的教导下,让我学会了如何做一名合格的大学生。......

关键字:单片机 郭天祥
发表评论 共有条评论
用户名: 验证码:

基于电磁感应的非接触供电技术

基于电磁感应的非接触供电技术

概述:LED照明产业发展迅猛,相关的LED照明技术也在逐步完善。照明设备的非接触供电技……

高电压测量用光电传输系统的仿真与实验研究

高电压测量用光电传输系统的仿真与实验研究

摘要:采用光电传输系统传输测量信号具有良好的绝缘性能和抗电磁干扰特性, 因而其在高……

VEMD6010X01参考设计电路|PIN光电二极管应用电路

VEMD6010X01参考设计电路|PIN光电二极管应用电路

VEMD6010X01 PIN光电二极管是高速高灵敏光电二极管,具有达 4x2x1.05mm 的较小表面安装……

项目外包